home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / umich / falcon / programm.ing / nt_dsp1.lzh / NT_DSP1.MSA / FLOAT / FPFIX.ASM < prev    next >
Assembly Source File  |  1989-01-24  |  4KB  |  108 lines
  1. ;
  2. ; This program originally available on the Motorola DSP bulletin board.
  3. ; It is provided under a DISCLAIMER OF WARRANTY available from
  4. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  5. ; 
  6. ; Last Update 5 Oct 87   Version 2.0
  7. ;
  8. fpfix   ident   2,0
  9. ;
  10. ; MOTOROLA DSP56000/1 FPLIB - VERSION 2
  11. ;
  12. ; FPFIX - FLOATING POINT TO FIXED POINT CONVERSION SUBROUTINE
  13. ;
  14. ; Entry points: fix_a   D = fix(A)
  15. ;               fix_x   D = fix(X)
  16. ;
  17. ;       m = 24 bit mantissa (two's complement, normalized fraction)
  18. ;
  19. ;       e = 14 bit exponent (unsigned integer, biased by +8191)
  20. ;
  21. ;       data = 56 bit fixed point data in standard integer/fractional
  22. ;              accumulator data representation.
  23. ;
  24. ; Input variables:
  25. ;
  26. ;   X   x1 = mx  (normalized)
  27. ;       x0 = ex
  28. ;
  29. ;   A   a2 = sign extension of ma
  30. ;       a1 = ma  (normalized)
  31. ;       a0 = zero
  32. ;
  33. ;       b2 = sign extension of ea (always zero)
  34. ;       b1 = ea
  35. ;       b0 = zero
  36. ;
  37. ; Output variables:
  38. ;
  39. ;   D    a = data
  40. ;
  41. ; Error conditions:     Set CCR L=1 if conversion overflow error.  That is,
  42. ;                       the input value was larger than +/- 256 and could
  43. ;                       not be represented in the standard 56 bit accumulator
  44. ;                       format.  Result is the maximum 56 bit fixed point
  45. ;                       value having the same sign as the floating point
  46. ;                       mantissa.  The CCR L bit remains set until cleared
  47. ;                       by the user.
  48. ;
  49. ; Assumes n0, m0, shift constant table and scaling modes
  50. ; initialized by previous call to the subroutine "fpinit".
  51. ;
  52. ; Alters Data ALU Registers
  53. ;       a2      a1      a0      a
  54. ;       b2      b1      b0      b
  55. ;               x0      y1
  56. ;
  57. ; Alters Address Registers
  58. ;       r0
  59. ;
  60. ; Alters Program Control Registers
  61. ;       pc      sr
  62. ;
  63. ; Uses 0 locations on System Stack
  64. ;
  65. ;
  66. fix_x   tfr     x0,b    x1,a            ;get mx,ex
  67. fix_a   tst     a       fp_space:fp_ebias,x0    ;check ma, get bias
  68.         jeq     done                    ;jump if ma = 0
  69.         sub     x0,b    #>8,x0          ;remove ea bias, get shift limit
  70.         jlt     _eneg                   ;jump if exponent < 0
  71.         jeq     done                    ;jump if exponent = 0
  72. ;
  73. ; exponent > 0
  74. ;
  75.         cmp     x0,b                    ;check left shift limit
  76.         jgt     _ehigh                  ;jump if exponent > 8
  77.         rep     b                       ;shift left b bits
  78.         asl     a                       ;shift data left
  79.         rts
  80. _ehigh  or      #$40,ccr                ;set L=1 for conversion overflow
  81.         tst     a                       ;check sign of ma
  82.         jpl     _fix1                   ;jump if ma positive
  83.         clr     a                       ;limit to maximum negative 56 bit value
  84.         move    #$80,a2                 ;set extension word
  85.         rts
  86. _fix1   clr     a                       ;limit to maximum positive 56 bit value
  87.         not     a                       ;set most significant word
  88.         move    a1,a0                   ;set least significant word
  89.         move    #$7f,a2                 ;set extension word
  90.         rts
  91. ;
  92. ; exponent < 0
  93. ;
  94. _eneg   abs     b       #>24,x0         ;fix exponent, get right shift limit
  95.         sub     x0,b    b1,r0           ;check for underflow, save exponent
  96.         jge     _elow                   ;jump if fixed point underflow
  97.         move    fp_space:(r0+n0),x0     a,y1    ;lookup shift factor, get ma
  98.         mpy     -y1,x0,a                ;denormalize ma
  99.         rts
  100. _elow   jeq     _shift                  ;jump if exponent = -24
  101.         cmp     x0,b    b1,r0           ;check for underflow, save exponent
  102.         jge     zero                    ;jump if data underflow
  103.         move    fp_space:(r0+n0),x0     a,y1    ;lookup shift factor, get ma
  104.         mpy     -y1,x0,a                ;denormalize ma
  105. _shift  tfr     a,b     a2,a            ;shift down 24 bits more
  106.         move    b1,a0
  107.         rts
  108.